BBjWindow::addButton

Description

Creates a button in the BBjWindow.

Syntax

Return Value	Method
BBjButton	addButton(int ID, int x, int y, int width, int height, string title)
BBjButton	addButton(int ID, int x, int y, int width, int height, string title, string flags)

Parameters

Variable	Description
ID	Control ID number. It must be an integer between 1 and 32767 and be unique within a given top-level window.
x	Horizontal position of the upper-left corner of the control in current units.
y	Vertical position of the upper-left corner of the control in current units.
width	Width of the control in current units.
height	Height of the control in current units.
title	Title of the control. Including the '&' before a character in the title causes it to be an accelerator.
flags	Control flags, as follows:
	Flag $0001$ $0010$ $0800$ $1000$	Description Sets the control to be initially disabled. Sets the control to be initially invisible. Draws a recessed client edge around the control. Draws a raised edge around the control.

Return Values

Returns the created BBjButton object.

Remarks

None.

Example

REM Add a button to a window

REM Obtain the instance of the BBjAPI object
LET myAPI!=BBjAPI()

REM Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

REM Obtain the instance of the BBjSysGui object
LET mySysGui!=myAPI!.getSysGui()

REM Set addWindow param values
X=10
Y=10
WIDTH=200
HEIGHT=200
TITLE$="BBj Window"

REM Set the current context
mySysGui!.setContext(0)

REM Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

REM Add a button on the window
myRedButton! = myWindow!.addButton(101,50,100,90,30,"Red",$0800$)

REM Register the CALLBACK routines
CALLBACK(ON_BUTTON_PUSH,RED_BUTTON_PUSHED,mySysGui!.getContext(),myRedButton!.getID())
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

REM Process Events
PROCESS_EVENTS

REM Callback routine called when the red button is pressed
RED_BUTTON_PUSHED:
REM Create the BBjColor Object using colorNum constant
myColorRed! = mySysGui!.makeColor(mySysGui!.RED)
REM Set the button colors to RED
myRedButton!.setBackColor(myColorRed!)
RETURN

REM Callback routine called when the user closes the application window
APP_CLOSE:
RELEASE
RETURN